Към съдържанието

Наследяемост (Inheritance)

  • bubust
  • 7 129 прочитания

Урокът е от архива на сайта и е писан преди години. Някои бутони и менюта в програмите вече може да изглеждат различно.

Най-добрият начин за обяснение на VB .NET наследяемостта е да започнем с пример. Класовете в дадена апликация често имат родствени връзки един с друг. Да предположим, че информационната апликация за нашия Служител (Slujasht) съдържа обект Slujasht в класа CSlujasht представен в генерален аспект общ за всички служители--name, address, Zaplata и т.н.

Разбира се директорите на училището ще искат да имат различни права от тези които има секретарката. Основателно е да дефинираме допълнителни класове наречени CDirector и CSecretary, всеки със свои свойства и методи. От друга страна, директорът е служител (Slujasht), като няма причина да дефинираме две различни имена в двата случая. Неефективно е!

Ето защо е създадена наследяемастта. Първо, дефинираме класа CSlujasht, който има свойство Zaplata и метод IncZaplata:

' Slujasht class

Public Class CSlujasht

' Zaplata property е read/write

Private mdecZaplata As Decimal

Property Zaplata( ) As Decimal

Get

Zaplata = mdecZaplata

End Get

Set

mdecZaplata = Value

End Set

End Property

Public Overridable Sub IncZaplata(ByVal sngPercent As Single)

mdecZaplata = mdecZaplata * (1 + CDec(sngPercent))

End Sub

End Class

След това дефинираме класа CDirector:

' Director Class

Public Class CDirector

Inherits CSlujasht

' Calculate Zaplata нараства базирано на 5% увеличение

Overrides Sub IncZaplata(ByVal sngPercent As Single)

Me.Zaplata = Me.Zaplata * CDec(1.05 + sngPercent)

End Sub

End Class



Две неща трябва да отбележим тук. Първо реда:

Inherits CSlujasht

индикира, че класа CDirector наследява (inherits) членовете на класа CSlujasht. Обект от клас CDirector е обект и от тип CSlujasht. Ако дефинираме обект от тип CDirector:

Dim ceo As New CDirector

след това можем да извикаме свойство Zaplata, така:

ceo.Zaplata = 1000

Второ, ключовата дума Overrides в метод IncZaplata означава, че изпълнението на IncZaplata в CDirector е извикано наместо изпълнението в CSlujasht. Така че кодът:

ceo.IncZaplata

касае заплатата в обекта CDirector ceo базирана на пренасянето на разрешение. Присъствието на ключова дума Overridable в дефиницията на IncZaplata в класа CSlujasht, спесифицира, че класът наследяващ от базовия клас е допуснат да предефинира - override метода на базовия клас.

След това, дефинираме класа CSecretary, който също наследява от CSlujasht но изпълнява различно нарастване на заплатата за обект секретарка:

' Secretary Class - на секретарката

Public Class CSecretary

Inherits CSlujasht

' секретарките вземат 2%

Overrides Sub IncZaplata(ByVal sngPercent As Single)

Me.Zaplata = Me.Zaplata * CDec(1.02 + sngPercent)

End Sub

End Class

Сега можем да напишем код за упражнение на тези класове:

Dim ThePrincipal As New CDirector( )

Dim MySecretary As New CSecretary( )

' Set заплащане

ThePrincipal.Zaplata = 1000

MySecretary.Zaplata = 300

' Set Slujasht - Principal и incZaplata

Debug.Writeline("Principal before: " & CStr(ThePrincipal.Zaplata))

ThePrincipal.IncZaplata(0.4)

Debug.WriteLine("Principal after: " & CStr(ThePrincipal.Zaplata))

' Set Slujasht - Principal и inc Zaplata

Debug.Writeline("Principal before: " & CStr(ThePrincipal.Zaplata))

ThePrincipal.IncZaplata(0.4)

Debug.WriteLine("Principal after: " & CStr(ThePrincipal.Zaplata))

' Set Slujasht - Secretary и inc Zaplata

Debug.Writeline("Secretary before: " & CStr(MySecretary.Zaplata))

MySecretary.IncZaplata(0.4)

Debug.WriteLine("Secretary after: " & CStr(MySecretary.Zaplata))



Изходът в този случай е:

Principal before: 1000

Principal after: 1450

Secretary before: 300

Secretary after: 396

Можем да кажем следното за наследяемостта:

Ако клас B наследява от клас A, тогава всеки обект от клас B е също обект и от клас A и включва публични (public) свойства и методи (това е публичния интерфейс) на клас A. В този случай, клас A се нарича базов клас (base class), а клас B се нарича произхождащ клас (derived class). От друга страна, произхождащият клас може да предефинира (override) изпълнението на членове на базовия клас за собствени нужди.

Наследяването се изпълнява посредством ключова дума Inherits.

Ако трябва да дадем кратка дефиниция, наследяемостта е възможност нов клас да произхожда (наследява) от по-прост клас (базов клас - base class).

Произхождащият клас (derived class) наследява всички полета (fields), свойства (properties), и методи (methods) на базовия клас и може да модифицира поведението на всички тези свойства и методи на базовия клас чрез предефинирането им (overriding). А вие разбира се може да добавяте нови полета, свойства и методи към наследяващия клас (inherited class).



- Позволение за наследяване

Има две ключови думи, които влияят върху възможността за наследяване:

NotInheritable

Когато се употребява за дефиниране на клас:

Public NotInheritable Class InterfaceExample

класът не може да бъде използван като базов.

MustInherit

Когато се употребява за дефиниране на клас:

Public MustInherit Class InterfaceExample

обектите на този клас не могат да се създадат директно. Обектите от наследяващите класове могат да се създават, с други думи, MustInherit класове могат да се използват само (only) като базови класове.



- Overriding - предефиниране

Има няколко ключови думи, които контролират дали произхождащият клас ще може да предефинира ( "override") изпълнението в базовия клас:



Overridable

Позволява, но не изисква съответния член да бъде предефиниран "overridden". По подразбиране за членове Public e NotOverridable. Пример:

Public Overridable Sub IncZaplata( )



NotOverridable

Забранява предефиниране (overriding) на членове. По подразбиране за Public членове на класа.

MustOverride

Трябва да бъде предефиниран (overridden). Когато се използва тази ключова дума, дефиницията на члена се ограничава само до деклариращ ред, без изпълнение и без End Sub или End Function ред. Например:

Public MustOverride Sub IncZaplata( )

Отбележете,че когато клас модулът съдържа член MustOverride, след това самият клас трябва да се декларира като MustInherit.



Overrides

Противно на другите модификации, този модификатор принадлежи на произхождащия клас и индицира, че модифицирания член е предефинирания (overriding) член на базовия клас. Примерно:

Overrides Sub IncZaplata( )



- Правила за наследяване

В много обектно-ориентирани езици, като C++, класът може да наследява директно от повече от един базов клас. Нарича се multiple inheritance . VB .NET не поддържа мултинаследяемост. Не се разрешава такъв код:

' Director Class

Public Class CDirector 'INVALID

Inherits CSlujasht

Inherits CWorker

. . .

End Class

От друга страна, Class C може да наследява от Class B, който може да наследява от Class A, което оформя йерархия на наследяемост.

Класът може да изпълнява мултиинтерфейси чрез ключова дума Interface.



- MyBase, MyClass, Me

Ключова дума MyBase обезпечава връзка с базовия клас отвътре произхождащия клас. Ако искате да извикате член на базовия клас отвътре произхождащия клас може така:

MyBase.MemberName

където MemberNameе името на члена. Това ще разреши много неясноти, ако наследяващият клас има член със същото име. Ключова дума MyBase може да бъде използвана за извикване на конструктора на базовия клас в ред на инстанциране на член от този клас, така:

MyBase.New(...)

Отбележете, че MyBase не може да бъде използван за викане на членове на Private клас.

Visual Basic търси най-непосредствената версия в родителския клас за процедурата в заявка. Така че, ако Class C произлиза от Class B, който произлиза от Class A, извикването в Class C към:

MyBase.AProc

първо поглежда в Class B за съответна процедура с име AProc. Ако не я намери, след това VB търси в Class A за съответна процедура. (Под съответствие -matching, разбираме метод със същата аргументна сигнатура.) Ключовата дума MyClass обезпечава връзка с клас, в който ключовата дума се използва. Подобно на ключовата дума Me, с изключение когато се използва за викане на метод. За да илюстрираме разликата, нека да вземем клас с име Class1 и произхождащия клас с име Class1Derived. Всеки клас има метод IncZaplata:

Public Class Class1

Public Overridable Function IncZaplata(ByVal sZaplata As Single) As Single

IncZaplata = sZaplata * CSng(1.1)

End Function

Public Sub ShowIncZaplata(ByVal sZaplata As Single)

MsgBox(Me.IncZaplata(sZaplata))

MsgBox(MyClass.IncZaplata(sZaplata))

End Sub

End Class

Public Class Class1Derived

Inherits Class1

Public Overrides Function IncZaplata(ByVal sZaplata As Single) As Single

IncZaplata = sZaplata * CSng(1.2)

End Function

End Class

Сега нека вземем следния код, поставен в модула на формата:

Dim c1 As New Class1( )

Dim c2 As New Class1Derived( )

Dim c1var As Class1

c1var = c1

c1var.IncZaplata(1000) ' дава 1100, 1100

c1var = c2

c1var.IncZaplata(1000) ' дава 1200, 1100

Първото извикване на IncZaplata е направено използвайки променлива от тип Class1, която свързва с обект от тип Class1. В този случай и двете повиквания:

Me.IncZaplata

MyClass.IncZaplata

връщат същата стойност, защото викат IncZaplata от базовия клас Class1.

Докато във втория случай, променливата от тип Class1 държи връзка към обект от произхождащия клас, Class1Derived. В този случай, Me свързва към обект от тип Class1Derived, докато MyClass все още свързва към базовия клас Class1 където се появява ключовата дума MyClass. Tака,

Me.IncZaplata

връща 1200 докато:

MyClass.IncZaplata

връща 1100.


Споделете: