Към съдържанието

Класът ArrayList Class

  • bubust
  • 8 055 прочитания

Урокът е от архива на сайта и е писан преди години. Някои бутони и менюта в програмите вече може да изглеждат различно.

Можете да мислите за класа ArrayList като хибрид от Array и Collectionобекти, при което можете да работите с множество от стойности като че ли са масиви и колекции едновременно. Примерно можете да адресирате елементите по техните индекси, да ги сортирате, реверсирате (подреждате отзад напред) и търсите по последователността на стойностите или двоично както се прави при масиви; можете да добавяте елементи, да ги вмъквате на дадена позиция или да ги изтривате както правите при колекции. Обектът ArrayList има инициализиран капацитет--броя на слотовете във външната структура, която държи актуалните стойности - но ArrayList може автоматично да се разширява при нужда както могат колекциите. Въпреки това можете да оптимизирате кода си като изберете да инициализирате капацитета на ArrayList, като добър компромис между използвана памет и опасност от препокриване при разширяване на ArrayList.

` Създаване на ArrayList с капацитет по подразбиране от 11 елемента.

Dim al As New ArrayList

`Създаване на ArrayList с капацитет от 1000 елемента.

Dim al2 As New ArrayList(1000)

Можете да модифицирате капацитета , за да го разширите или свиете по всяко време чрез свойство Capacity. Но не можете да го направите по-малък от текущо съхранените елементи в масива, (което кореспондира със стойността на свойство Count):

` ArrayList заема точно толкова място в паметта, колкото е нужно.

al.Capacity = al.Count

` Друг начин за постигане на същия резултат

al.TrimToSize

Когато текущият капацитет се разшири, обектът ArrayList удвоява своя капацитет автоматично.

Друг начин за създаване на обект ArrayList е чрез споделения метод Repeat, който ви позволява да определите инициализиращата стойност за броя на елементите:

` Създаване на ArrayList със 100 елемента равни на нулев стринг.

Dim al As ArrayList = ArrayList.Repeat("", 100)

Класът ArrayList напълно представлява интерфейса IList interface. Можете да прибавите елементи към обект ArrayList като използвате метод Add (който добавя елемент след последния член (item) или метод Insert (който вмъква на определен индекс). Можете да изтриете обект с метод Remove, или да изтриете елемент на дадена позиция чрез метод RemoveAt, а може да изтриете всички елементи с метод Clear:

`Празен ArrayList.

al.Clear

` Добавяне на елементите "Pavel" и "Ana" на края на списъка ArrayList.

al.Add("Pavel")

al.Add("Ana")

` Вмъкване на елемент "Robert" в началото на списъка. (Индексите са 0-безирани.)

al.Insert(0, "Robert")

` Изтриване на "Pavel" от списъка.

al.Remove("Pavel")

` Изтриване на първия елемент от списъка("Robert" в случая).

al.RemoveAt(0)

Методът Remove изтрива само първия срещнат елемент, така че трябва да организирате цикъл за изтриване на всички елементи със същата стойност. Не можете просто да преминавате през цикъла до грешка, защото методът Remove не хваща грешка ако елементът не е намерен. По тази причина трябва да използвате един от тези два начина:

` Използвайки метод IndexOf .

` (може също метод Contains)

Do While al.IndexOf("element to remove") >= 0

al.Remove("element to remove")

Loop

` По-ефективна техника: циклене докато свойство Count получи константа.

Dim saveCount As Integer

Do

saveCount = al.Count

al.Remove("element to remove")

Loop While al.Count < saveCount

Можете да прочетете елемент от ArrayList чрез свойство Item.

Това е подразбиращото се свойство (default), така че може да го пропуснете. Основната разлика между реалните масиви и обектите ArrayList е, че елементът на ArrayList се създава само когато се извика метод Add, така че не може да работите с елемент, чийто индекс е равен или по-голям на свойството Count на ArrayList:

al(0) = "first element"

Като при колекциите, предпочитания начин за итерации е цикъл For Each:

Dim o As Object

For Each o In al

Console.WriteLine(o)

Next



Създаване на ненулево базирани масиви (Nonzero-Based Arrays)

Методът GetLowerBound може да изглежда излишен, защото всички масиви са нулево базирани, тоест започват с индекс 0. Въпреки това, има възможност да създадете масив стартиращ от друг индекс чрез споделения метод Array.CreateInstance, макар че изискваният синтаксис е сложен:

Sub TestArraysWithNonZeroLBound()

' Създаване на двудименсионален масив, който е еквивалентен

' на следната Visual Basic 6 декларация:

' Dim(1 To 5, -10 To 10) As Integer

' Приготвяне на auxiliary array дължина за всяка дименсия.

Dim lengths() As Integer = {5, 21}

' auxiliary array със стартов индекс за всяка дименсия

Dim lbounds() As Integer = {1, -10}

' създаване на генеричен обект Array object от споделения CreateInstance метод.

Dim arrObj As Array = _

Array.CreateInstance(GetType(Integer), lengths, lbounds)

' присвояването му на масив с правилния ранг.

Dim arr(,) As Integer = CType(arrObj, Integer(,))

' изпробване дали това работи.

Console.WriteLine(arr.GetLowerBound(0)) ' => 1

Console.WriteLine(arr.GetUpperBound(0)) ' => 5

Console.WriteLine(arr.GetLowerBound(1)) ' => -10

Console.WriteLine(arr.GetUpperBound(1)) ' => 10

' присвояване на елемент, и прочитането му.

arr(1, -1) = 1234

Console.WriteLine(arr(1, -1)) ' => 1234

End Sub

Този начин е добър за мулти-дименсионални масиви, но за едно-дименсионални не се препоръчва.



Копиране на масиви (Copying Arrays)

Класът Array поддържа интерфейса ICloneable, така че можете да създадете празно копие на масив използвайки методът за инстанциране Clone.

`работи ако Option Strict is Off.

Dim anotherArray(,) As Integer = arr.Clone

` този синтаксис се изисква ако Option Strict is On.

` (може да използвате CType вместо DirectCast.)

Dim anotherArray(,) As Integer = DirectCast(arr.Clone, Integer())

You can copy a one-dimensional array to another, and you decide the starting index in the destination array:

` създадане и инициализираме на масив (10 елемента).

Dim sourceArr() As Integer = {1, 2, 3, 5, 7, 11, 13, 17, 19, 23}

`създаване на целеви масив (трябва да е със същия размер или по-голям).

Dim destArr(20) As Integer

` копиране на масива източник във втората половина на целевия масив.

sourceArr.CopyTo(destArr, 10)

Обърнете внимание на важен детайл: индексът в целевия масив е актуално отместването от стартовия индекс на масива. Ако целевия масив е 0-базиран (каквито са всички масиви декларирани с оператор Dim), вие можете да подадете индекса на първия елемент, който ще бъде презаписан в целевия масив. Докато ако използвате Array.CreateInstance за създаване на масив, чийто най-нисък индекс е различен от 0, вие трябва съответно да модифицирате втория аргумент на метода CopyTo .

Примерно ако масива е 1-базиран, подайте стойност 9 така че destArr(10) да е първият презаписан елемент.


Сортиране на елементи (Sorting Elements)

Класът Array предлага някои споделени методи за процедиране с масиви лесно и бързо. Един от тях е метод Array.Sort. Вие можете да сортирате масиви, използвайки арбитражна група от клавиши* под интерфейси IComparable и IComparer.

Методът Sort е много гъвкав. Примерно, можете да сортирате само порция от масив:

` сортиране само на елементите[10,100] от целевия масив targetArray.

` вторият аргумент е стартовия индекс; последния аргумент е дължината на подмасива.

Array.Sort(targetArray, 10, 91)

Можете също да сортирате масив от стойности използвайки друг масив, който съдържа сортиращите ключове* , което ви позволява да сортирате масиви от структури или обекти. За да се види как тази overloaded версия на метод Sort работи, нека да стартираме дефинирането на структура:

Structure Employee

Public FirstName As String

Public LastName As String

Public HireDate As Date

Sub New(ByVal firstName As String, ByVal lastName As _ String,ByVal hireDate As Date)

Me.FirstName = firstName

Me.LastName = lastName

Me.HireDate = hireDate

End Sub

' функция за лесно разпечатване на елементните свойства

Function Description() As String

Return FirstName & " " & LastName & _

" (hired on " & HireDate.ToShortDateString & ")"

End Function

End Structure

Следният код създава главния масив (main array) на структурата Employee, която създава извънредния ключов масив, който съдържа датата "hiring date" на всеки служител (employee), и накрая сортира главния масив, използвайки извънредния масив:

`създаване на тестов масив.

Dim employees() As Employee = { _

New Employee("Pavel", "Doe", #3/1/2001#), _

New Employee("Robert", "Smith", #8/12/2000#), _

New Employee("Ana", "Douglas", #11/1/1999#)}

` създаване на паралелен масив от hiring dates.

Dim hireDates(UBound(employees)) As Date

Dim j As Integer

For j = 0 To employees.Length - 1

hireDates(j) = employees(j).HireDate

Next

` сортиране на масива Employees използвайке HireDates за ключове.

Array.Sort(hireDates, employees)

` пробване дали масивът е сортиран по поле HireDate.

For j = 0 To employees.Length - 1

Console.WriteLine(employees(j).Description)

Next

Най-интересното е, че ключовият масив е сортиран и затова не се нуждае от повторна инициализация, когато се добавя друг елемент към главния масив:

` добавяне на четвърти служител (employee).

ReDim Preserve employees(3)

employees(3) = New Employee("Chris", "Doe", #5/9/2000#)

`разшряване на ключовия масив -няма нужда от повторна инизиализация.

ReDim Preserve hireDates(3)

hireDates(3) = employees(3).HireDate

`пресортиране на новия, по-дълъг масив.

Array.Sort(hireDates, employees)

Така overloaded версията на метода Sort ви дава възможност да сортирате порция от масив от стойности, за които имате обезпечение от масива от ключове. Това е особено полезно, когато стартирате с дълъг масив, който запълвате само на порции"

`създаване на test array с много място.

Dim employees(1000) As Employee

`инициализация само на първите му четири елемента.

Array.Sort(hireDates, employees, 0, 4)

Всички версии на метод Array.Sort могат да използват допълнително обект IComparer, който диктува как да се сравняват един с друг елементите или ключовете на масива.

Методът Array.Reverse реверсира реда на елементите на масива или на порцията от масива, така че може да се долепи веднага след сортирането, за да се получи сортиране по обратен ред:

`сортиране на целочисления масив в обратен (реверсивен) ред.

Array.Sort(intArray)

Array.Reverse(intArray)

Когато става въпрос за порция от масив трябва да подадете началния индекс и броя на елементите за реверсиране:

` реверсиране само на първите 10 елемента в масивintArray.

Array.Reverse(intArray, 0, 10)



Нулиране (Clearing), копиране (Copying), и местене (Moving) на елементи

Може да нулирате порция от масив с метод Clear, без цикъл For:

` нулиране на елементи[10,100] на масива.

Array.Clear(arr, 10, 91)

Методът Array.Copy ви дава възможност да копирате елементите от едно-дименсионален масив в друг масив. Има две предефинирани (overloaded) версии на този метод. Първата версия копира даден брой елементи от масива източник в масива получател:

Dim intArr() As Integer = {1, 2, 3, 4, 5, 6, 7, 8, 9, 10}

Dim intArr2(20) As Integer

`копиране на масива източник в първата половина на целевия масив.

Array.Copy(intArr, intArr2, 10)

Dim i As Integer

For i = 0 To 20

Console.Write(CStr(intArr2(i)) & " ")

' => 1 2 3 4 5 6 7 8 9 10 0 0 0 0 0 0 0 0 0 0 0

Next

Втората версия ви оставя да решите кой е стартовия индекс за масива източник, и кой е стартовия индекс за масива получател (това е индексът на първият елемент, който ще се презапише), и броя на елементите за копиране:

`копиране на елементите с индекси 5-9 към края на масив destArr.

Array.Copy(intArr, 5, intArr2, 15, 5)

`това е първият елемент, който ще се копира.

Console.WriteLine(intArr2(15)) ' => 6

Вие получавате грешка от типа ArgumentOutOfRangeException ако подавате грешни стойности за индексите или ако масивът получател не е достатъчно дълъг, както получавате грешка от типа RankException ако всеки масив има две или повече размерности (дименсии).

Методът Copy работи коректно даже и ако масива източник и масива получател имат различни типове, но в такъв случай се налага да се провери индивидуално елемента източник спрямо кореспондиращия елемент в масива получател. Актуалното поведение зависи от много фактори, като например дали масива източник или масива получател са от стойностен тип или референтен тип. Примерно, вие можете да копирате от всеки масив в обектен масив (Object array), от целочислен масив (Integer) в масив Long, и от Single масив в масив Double, защото те са разширяващи конверсии и не могат да се сринат. Копирайте посредством изключение TypeMismatchException когато очаквате недостигаща конверсия между масиви от стойностен тип, дори и индивидуалните елементи на масива източник да са успешно конвертирани към стойностите на масива получател:

`тази операция Copy се извършва даже и ако типовете на масивите са различни.

Dim intArr3() As Integer = {1, 2, 3, 4, 5, 6, 7, 8, 9, 10}

Dim lngArr3(20) As Long

Array.Copy(intArr3, lngArr3, 10)

`тази операция Copy пропада с TypeMismatchException.

Dim lngArr4() As Long = {1, 2, 3, 4, 5, 6, 7, 8, 9, 10}

Dim intArr4(20) As Integer

Array.Copy(lngArr4, intArr4, 10)

За сравнение, ако копирате от или във референтен тип масив, методът

Array.Copy опитва да копира всеки елемент; ако се получи грешка Invalid-

CastException за елемент, методът не копира този елемент нито стойността му след това.

Интересна черта на метода Array.Copy: способността за копиране на порция от масив върху себе си. В този случай, методът Copy извършва "smart copy," в смисъл че елементите се копират коректно във възходящ ред, ако копирате към ниския индекс, или в обратен ред, ако копирате към високия индекс. Така можете да използвате метода Copy за да изтриете един или повече елемента и да запълните дупката в масива, което като резултат е преместване на всички следващи елементи на една или повече позиции спрямо ниския индекс:

Dim lngArr5() As Long = {1, 2, 3, 4, 5, 6, 7, 8, 9, 10}

`изтрива елемент с индекс 4.

Array.Copy(lngArr5, 5, lngArr5, 4, 5)

` комплектова операцията по изтриванет с нулиране на последния елемент.

Array.Clear(lngArr5, lngArr5.GetUpperBound(0), 1)

`сега масивът съдържа: {1, 2, 3, 4, 6, 7, 8, 9, 10, 0}

Reading 4 Arrays, Lists, and Collections 83

Можете да използвате този код за база на преизползваема подпрограма, която работи с всеки тип масив:

Sub ArrayDeleteElement(ByVal arr As Array, ByVal index As Integer)

' премества елементите от arr(index+1) във arr(index).

Array.Copy(arr, index + 1, arr, index, UBound(arr) - Index)

' нулиране на последния елемент.

arr.Clear(arr, arr.GetUpperBound(0), 1)

End Sub

Вмъкването на елемент е също лесно, и отново може да създадете родова подпрограма за работа с масиви от всеки тип:

Sub ArrayInsertElement(ByVal arr As Array, ByVal index As Integer, _

Optional ByVal newValue As Object = Nothing)

' премества елементите от arr(index) във arr(index+1)за да се освободи място.

Array.Copy(arr, index, arr, index + 1, arr.Length - index - 1)

' присвоява елемент използвайки метод SetValue.

arr.SetValue(newValue, index)

End Sub

Класът Array class представя методите SetValue и GetValue за присвояване и четене на елементи; нормално няма да ги ползвате в обикновените програми, но те са полезни в родови подпрограми (като двете предишни подпрограми) които работят с всеки тип масив. SetValue и GetValue са също полезни за работа с елементи от масиви несъвместими с CLS (non-CLS-compliant arrays) с ненулев нисък индекс.

Можете да използвате Copy с мулти-дименсионални масиви, като в този случай масивите се третират като едно-дименсионални с всички редове поставени един след друг в паметта.



Търсене на стойности (Searching Values)

Методът IndexOf търси в масива за стойност и връща индекса на първия елемент, който съответствува или -1 ако няма съответствие:

Dim strArray() As String = {"Robert", "Pavel", "Ana", "Chris", "Pavel"}

Console.WriteLine(Array.IndexOf(strArray, "Ana")) ' => 2

Console.WriteLine(Array.IndexOf(strArray, "ANA")) ' => -1

По-прецизно, IndexOf връща стойността на най-ниския индекс минус 1

ако няма съответствие; тази разлика е важна ако масива не е 0-базиран. Можете да специфицирате стартовия индекс и опционално крайния индекс; ако крайния индекс се пропусни, търсенето продължава до края на масива.

Може да използвате тази предефинирана (overloaded) форма, за да намерите всички стойности в масива като зададената:

`търсене на всички съвпадения на стринг "Pavel".

Dim index As Integer = -1

Do

'търсене на следващо попадение.

index = Array.IndexOf(strArray, "Pavel", index + 1)

' ако не е намерено Exit на цикъла.

If index = -1 Then Exit Do

Console.WriteLine("Found at index {0}", index)

Loop

Предшестващият цикъл показва следното съобщение в конзолния прозорец:

Found at index 1

Found at index 4

Методът LastIndexOf е подобен на IndexOf с изключение че връща индекса на последната съвпаднала стойност.

Понеже търсенето е отзад напред, трябва крайния подаден индекс да е по-голям от първия подаден:

`търсене от най-високия индекс към началото на масива.

index = strArr.Length

Do

index = Array.LastIndexOf(strArr, "Pavel", index - 1)

If index = -1 Then Exit Do

Console.WriteLine("Found at index {0}", index)

Loop

Методите IndexOf и LastIndexOf провеждат линейно търсене, което е бавно при огромни масиви. Много по-бърз код ако масивът е сортиран е двоичното търсене, т.е. използването но метод BinarySearch:

` (Binary) двоично търсене на сортиран масив

Dim strArr2() As String = {"Ana", "Chris", "Pavel", "Robert", "Sam"}

Console.WriteLine(Array.BinarySearch(strArr2, "Chris")) ' => 1

Ако не се намери елемента, методът връща отрицателна стойност, който е побитов обратен код на индекса на първия елемент, който е по-голям от търсената стойност. Това помага да се определи къде да се вмъкне стойност в сортиран масив:

index = Array.BinarySearch(strArr2, "David")

If index >= 0 Then

Console.WriteLine("Found at index {0}", index)

Else

' инвертиране на резултата за да се даде индекса преди точката на вмъкване.

index = Not index

Console.WriteLine("Not Found. Insert at index {0}", index)

' => Not found. Insert at index 2

End If

Можете да подадете стартов индекс и дължината на порцията от масива от точката в която искате да започнете търсенето, което е полезно, когато работите с масив, който е частично запълнен само:

Console.Write(Array.BinarySearch(strArr2, 0, 3, "Chris"))'=> 1

Накрая, и двете синтактични форми на метод BinarySearch поддържат обект IComparer в края на списъка на аргументите, което ви дава възможност да определите как се сравняват елементите. На практика можете да използвате същия обект IComparer, който подавате на метод Sort, за да сортирате масива.


Класът ArrayList class

Класът ArrayList представя методи, които позволяват да се манипулират области (ranges) от елементи в една операция. Методът AddRange добавя към текущия обект ArrayList всички елементи съдържащи се в друг обект, който изпълнява интерфейса ICollection. Много класове .NET изпълняват ICollection, като колекция на всички членове (items) в контрола списъчна кутия (List-Box) и колекцията от възли в контрол Йерархичен изглед (TreeView). Следващата подпрограма взема два обекта ArrayList и връща трети ArrayList който съдържа всички членове на двата аргумента:

Function ArrayListJoin(ByVal al1 As ArrayList, ByVal al2 As ArrayList) _

As ArrayList

ArrayListJoin = New ArrayList(al1.Count + al2.count)

ArrayListJoin.AddRange(al1)

ArrayListJoin.AddRange(al2)

End Function

Методът InsertRange работи по подобен начин, но ви оставя да вмъкнете много елементи до всеки индекс в текущия обект ArrayList:

`вмъква всички елементи от al2 в началото на текущия ArrayList.

al.InsertRange(0, al2)

RemoveRange изтрива много елементи в текущия обект ArrayList :

` изтрива последните четири елемента

al.RemoveRange(al.Count - 4, 4)

можете бързо да извлечете всички членове в обект ArrayList чрез използване на метод ToArray или CopyTo метод. Двата метода поддържат едно-дименсионален (one-dimensional) целеви масив от всеки тип, но последният позволява да се извлече подмножество от ArrayList:

Dim objArr() As Object = al.ToArray()

Dim strArr() As String = CType(al.ToArray(GetType(String)), String())

Dim strArr2(al.Count) As String

al.CopyTo(strArr2)

Dim strArr3() As String = {"0", "1", "2", "3", "4", "5", "6", "7", "8", "9"}

al.CopyTo(0, strArr3, 4, 2)

Класът ArrayList поддържа други полезни методи, като Sort, SortRange,

BinarySearch, IndexOf, LastIndexOf, и Reverse.

Последната характеристика на класа ArrayList е неговия споделен метод Adapter. Този метод взема IList-произхождащия обект като негов единствен аргумент и създава ArrayList обвивка около този обект. С други думи вместо да създава копие на аргумента, метод Adapter създава обект ArrayList, който "съдържа" оригиналната колекция: всички промени които правите на външния ArrayList обект се дублират и във вътрешната колекция.

Следният код демонстрира как да използваме тази техника да реверсираме (или сортираме и т.н.) всички членове в контрол ListBox:

`създава обвивка около Listbox.Items IList колекцията.

Dim lbAdapter As ArrayList = ArrayList.Adapter(ListBox1.Items)

` реверсира реда им.

lbAdapter.Reverse()

Ако не мислите да използвате ArrayList, можете да направите кода по-кратък:

ArrayList.Adapter(ListBox1.Items).Reverse
Споделете: